home *** CD-ROM | disk | FTP | other *** search
/ Shareware Grab Bag / Shareware Grab Bag.iso / 010 / werewolf.bas (.txt) < prev    next >
Encoding:
GW-BASIC  |  1985-09-15  |  13.0 KB  |  369 lines
  1. 1  SAVE"WEREWOLF
  2. 10  REM WEREWOLVES AND WANDERER
  3. 11  REM UPGRADED VERSION
  4. 20  GOSUB 2600:REM INITIALIZE
  5. 30  GOSUB 160
  6. 40  IF RO <> 11 THEN 30
  7. 50  PRINT :PRINT "YOU'VE DONE IT!!":GOSUB 3520:PRINT "THAT WAS THE EXIT FROM THE CASTLE"
  8. 60  GOSUB 3520
  9. 70  PRINT:PRINT "YOU HAVE SUCCEEDED, ";N$;"!"
  10. 80  PRINT:PRINT "YOU MANAGED TO GET OUT OF THE CASTLE"
  11. 90  GOSUB 3520
  12. 100  PRINT:PRINT "WELL DONE!"
  13. 110  GOSUB 3520
  14. 120  PRINT :PRINT "YOUR SCORE IS";
  15. 130  PRINT 3*TALLY+5*STRENGTH+2*WEALTH+FOOD+30*MK
  16. 140  KEY ON:SYSTEM:END
  17. 150  REM **********************
  18. 160  REM MAJOR HANDLING ROUTINE
  19. 170  STRENGTH=STRENGTH-5
  20. 180  IF STRENGTH<10 THEN PRINT "WARNING, ";N$;", YOUR STRENGTH":PRINT "IS RUNNING LOW":PRINT
  21. 190  IF STRENGTH<1THEN 2300:REM DEATH
  22. 200  TALLY=TALLY+1
  23. 210  PRINT N$;",YOUR STRENGTH IS";STRENGTH
  24. 220  IF WEALTH>0 THEN PRINT "YOU HAVE $";WEALTH
  25. 230  IF FOOD>0 THEN PRINT "YOUR PROVISIONS SACK HOLDS";FOOD;"UNITS OF FOOD"
  26. 240  IF SUIT=1 THEN PRINT "YOU ARE WEARING ARMOR"
  27. 250  IF AXE=0 AND SWORD=0 AND AMULET=0 THEN 320
  28. 260  PRINT "YOU ARE CARRYING ";
  29. 270  IF AXE=1 THEN PRINT "AN AXE ";
  30. 280  IF SWORD=1 THEN PRINT "A SWORD ";
  31. 290  IF SWORD+AXE>0 AND AMULET=1 THEN PRINT "AND ";
  32. 300  IF AMULET=1 THEN PRINT "THE MAGIC AMULET"
  33. 310  PRINT
  34. 320  IF LIGHT=0 THEN PRINT "IT IS TOO DARK TO SEE ANYTHING"
  35. 330  IF LIGHT=1 THEN GOSUB 990:REM ROOM DESCRIPTION
  36. 340  K=A(RO,7):REM K IS SET TO CONTENTS OF ROOM
  37. 350  IF K=0 THEN 440:REM ROOM IS EMPTY
  38. 355  M=RND(1)
  39. 357  IF K>9 AND M<=0.5 THEN PRINT "THERE ARE GEMS HERE WORTH $";K:GOTO 440
  40. 360  IF K>9 AND M>0.5 THEN PRINT "THERE IS TREASURE HERE WORTH $";K:GOTO 440
  41. 370  PRINT:PRINT:PRINT "DANGER...THERE IS A MONSTER HERE....":GOSUB 3520
  42. 380  IF K=-1 THEN M$="FEROCIOUS WEREWOLF":FF=5
  43. 390  IF K=-2 THEN M$="FANATICAL FLESHGORGER":FF=10
  44. 400  IF K=-3 THEN M$="MALOVENTY MALDEMER":FF=15
  45. 410  IF K=-4 THEN M$="DEVASTATING ICE-DRAGON":FF=20
  46. 415  IF K=-5 THEN M$="HORRENDOUS HODGEPODGER":FF=25
  47. 416  IF K=-6 THEN M$="GHASTLY GRUSOMENESS":FF=30
  48. 420  PRINT:PRINT "IT IS A ";M$
  49. 430  PRINT:PRINT "THE DANGER LEVEL IS";FF;"!!"
  50. 440  GOSUB 3520
  51. 450  PRINT:PRINT:PRINT "WHAT DO YOU WANT TO DO";
  52. 460  INPUT A$:A$=LEFT$(A$,1)
  53. 470  IF K<0 AND A$<>"F" AND A$<>"R" THEN 460
  54. 480  PRINT:PRINT:PRINT "---------------------------------------------------------------------------":PRINT
  55. 490  IF A$="Q" THEN 120
  56. 500  IF A$="N" AND A(RO,1)=0 THEN PRINT "NO EXIT THAT WAY":GOTO 440
  57. 510  IF A$="S" AND A(RO,2)=0 THEN PRINT "THERE IS NO EXIT SOUTH":GOTO 440
  58. 520  IF A$="E" AND A(RO,3)=0 THEN PRINT "YOU CANNOT GO IN THAT DIRECTION":GOTO 440
  59. 530  IF A$="W" AND A(RO,4)=0 THEN PRINT "YOU CANNOT MOVE THROUGH STONE":GOTO 440
  60. 540  IF A$="U" AND A(RO,5)=0 THEN PRINT "THERE IS NO WAY UP FROM HERE":GOTO 440
  61. 550  IF A$="D" AND A(RO,6)=0 THEN PRINT "YOU CANNOT DESCEND FROM HERE":GOTO 440
  62. 560  IF A$="R" AND RND(1)>0.7 THEN 2420
  63. 570  IF A$="R" THEN K=0:PRINT "WHICH WAY DO YOU WANT TO RUN AWAY";:GOTO 460
  64. 580  IF A$="F" AND A(RO,7)>-1 THEN PRINT "THERE IS NOTHING TO FIGHT HERE":GOTO 40
  65. 590  IF A$="I" THEN GOSUB 3010:RETURN
  66. 600  IF A$="C" AND FOOD=0 THEN PRINT "YOU HAVE NO FOOD":GOTO 440
  67. 610  IF A$="P" THEN GOSUB 2350:RETURN
  68. 620  IF A$="F" THEN 730
  69. 625  IF A$="M" THEN FOR J=1 TO 30:PRINT TAB(J);"*":NEXT J
  70. 630  IF A$="M" THEN RO=INT(RND(1)*19)+1:IF RO=6 OR RO=11 THEN 630 ELSE 710
  71. 640  IF A$="C" THEN GOSUB 2480:RETURN
  72. 650  IF A$="N" THEN RO=A(RO,1)
  73. 660  IF A$="S" THEN RO=A(RO,2)
  74. 670  IF A$="E" THEN RO=A(RO,3)
  75. 680  IF A$="W" THEN RO=A(RO,4)
  76. 690  IF A$="U" THEN RO=A(RO,5)
  77. 700  IF A$="D" THEN RO=A(RO,6)
  78. 705  IF A$="T" THEN PRINT "YOUR TALLY AT PRESENT IS";3*TALLY+5*STRENGTH+2*WEALTH+FOOD+30*MK
  79. 706  IF A$="T" AND RND>0.5 THEN PRINT:PRINT "YOU HAVE KILLED";MK;"MONSTERS SO FAR..."
  80. 710  RETURN
  81. 720  REM ******************************
  82. 730  REM FIGHT
  83. 740  IF INKEY$<>"" THEN 740
  84. 750  PRINT "PRESS ANY KEY TO FIGHT"
  85. 760  IF INKEY$="" THEN 760
  86. 770  IF SUIT=1 THEN PRINT "YOUR ARMOR INCREASES YOUR CHANCE OF SUCCESS":FF=3*(INT(FF/4)):GOSUB 3520
  87. 780  CLS:FOR J=1 TO 6:PRINT "*_*_*_*_*_*_*_*_*_*_*_*_*_*_*_*_*_*_*_*_*_*":NEXT J
  88. 790  IF AXE=0 AND SWORD=0 THEN PRINT "YOU HAVE NO WEAPONS":PRINT "YOU MUST FIGHT WITH YOUR BARE HANDS":FF=INT(FF+FF/5):GOTO 870
  89. 800  IF AXE=1 AND SWORD=0 THEN PRINT "YOU HAVE ONLY AN AXE TO FIGHT WITH":FF=4*INT(FF/5):GOTO 870
  90. 810  IF AXE=0 AND SWORD=1 THEN PRINT "YOU MUST FIGHT WITH YOUR SWORD";FF=3*INT(FF/4):GOTO 870
  91. 820  INPUT "WHICH WEAPON? 1 - AXE, 2 - SWORD";Z
  92. 830  IF Z<1 OR Z>2 THEN 820
  93. 840  IF Z=1 THEN FF=4*INT(FF/5)
  94. 850  IF Z=2 THEN FF=3*INT(FF/4)
  95. 860  REM *************************
  96. 870  REM THE BATTLE
  97. 880  PRINT:PRINT
  98. 890  IF RND(1)>0.5 THEN PRINT M$;" ATTACKS" ELSE PRINT "YOU ATTACK"
  99. 900  GOSUB 3520
  100. 905  IF RND>0.5 AND LIGHT=1 THEN PRINT "YOUR TORCH WAS KNOCKED FROM YOUR HAND":LIGHT=0:GOSUB 3520
  101. 906  IF RND>0.5 AND AXE=1 THEN PRINT "YOU DROP YOUR AXE IN THE HEAT OF BATTLE":AXE=0:FF=5*INT(FF/4)
  102. 907  IF RND>0.5 AND SWORD=1 THEN PRINT "YOUR SWORD IS KNOCKED FROM YOUR HAND!!!":SWORD=0:FF=4*INT(FF/3)
  103. 910  IF RND(1)>0.5 THEN PRINT:PRINT "YOU MANAGE TO WOUND IT":FF=INT(5*FF/6)
  104. 911  IF RND>0.95 THEN PRINT "AAAAARGH!!!":GOSUB 3520:PRINT "RIP! TEAR! RIP!"
  105. 912  IF RND>0.9 THEN PRINT "YOU WANT TO RUN, BUT YOU STAND YOUR GROUND..."
  106. 913  IF RND>0.9 THEN PRINT "@&%@$#$% $%# !! @ #$$#  #$@!  #$ $#$ !!!"
  107. 914  IF RND>0.7 THEN PRINT "WILL THIS BE A BATTLE TO THE DEATH?"
  108. 915  IF RND>0.7 THEN PRINT "I REALLY WANNA FUCK YOU....OOOHH!!"
  109. 916  IF RND>0.7 THEN PRINT "BLOOD DRIPS FROM HIS CLAWS"
  110. 917  IF RND>0.7 THEN PRINT "YOU SMELL THE SULPHUR ON HIS BREATH"
  111. 918  IF RND>0.7 THEN PRINT "HE STRIKES WILDLY, MADLY..........."
  112. 919  IF RND>0.7 THEN PRINT "YOU HAVE NEVER FOUGHT AN OPPONENT LIKE THIS!!"
  113. 920  GOSUB 3520
  114. 930  IF RND(1)>0.5 THEN PRINT:PRINT "THE MONSTER WOUNDS YOU!":STRENGTH=STRENGTH-5
  115. 940  IF RND(1)>0.35 THEN 890
  116. 950  IF RND(1)*16>FF THEN PRINT:PRINT "AND YOU MANAGED TO KILL THE ";M$:MK=MK+1:GOTO 970
  117. 960  PRINT:PRINT "THE ";M$;" DEFEATED YOU":STRENGTH=INT(STRENGTH/2)
  118. 970  A(RO,7)=0:GOSUB 3520:PRINT:PRINT:GOSUB 3520:RETURN
  119. 980  REM *****************
  120. 990  REM ROOM DESCRIPTIONS
  121. 1000  PRINT:PRINT "******************************":PRINT:PRINT
  122. 1010  ON RO GOSUB 1040,1100,1170,1230,1280,1360,1410,1470,1540,1620,1700,1730,1790,1860,1960,2030,2100,2160,2230
  123. 1020  RETURN
  124. 1030  REM ************
  125. 1040  REM ROOM 1
  126. 1050  PRINT "YOU ARE IN THE HALLWAY"
  127. 1055  IF RND>0.4 THEN PRINT "FROM THE DUST, YOU CAN TELL THAT NO ONE HAS WALKED HERE IN A LONG, LONG TIME"
  128. 1060  PRINT "THERE IS A DOOR TO THE SOUTH"
  129. 1070  PRINT "THROUGH WINDOWS TO THE NORTH YOU CAN SEE A SECRET HERB GARDEN"
  130. 1080  RETURN
  131. 1090  REM ************
  132. 1100  REM ROOM 2
  133. 1110  PRINT "THIS IS THE AUDIENCE CHAMBER"
  134. 1115  IF RND>0.4 THEN PRINT "THE FADED TAPE STRINGS ON THE WALL ONLY HINT AT THE SPLENDOR WHICH THIS ROOM":PRINT "ONCE HAD"
  135. 1120  PRINT "THERE IS A WINDOW TO THE WEST. BY LOOKING TO THE RIGHT, THROUGH IT YOU CAN SEE":PRINT "THE ENTRANCE TO THE CASTLE."
  136. 1150  RETURN
  137. 1160  REM ************
  138. 1170  REM ROOM 3
  139. 1180  PRINT "YOU ARE IN A GREAT HALL, AN L-SHAPED ROOM"
  140. 1190  PRINT "THERE ARE TWO DOORS IN THIS ROOM, THE WOOD PANELS ARE WARPED AND FADED..."
  141. 1205  IF RND>0.4 THEN PRINT "AS YOU STAND THERE, YOU HEAR A MOUSE SCAMPER ALONG THE FLOOR BEHIND YOU...":PRINT "YOU WHIRL AROUND...BUT SEE NOTHING!"
  142. 1210  RETURN
  143. 1220  REM ************
  144. 1230  REM ROOM 4
  145. 1240  PRINT "THIS IS THE MONARCH'S PRIVATE MEETING ROOM"
  146. 1245  IF RND<0.4 THEN PRINT "THE ECHO OF ANCIENT PLOTTING AND WRANGLING HANGS HEAVY IN THE MUSTY AIR..."
  147. 1250  PRINT "THERE IS A SINGLE EXIT TO THE SOUTH"
  148. 1260  RETURN
  149. 1270  REM ************
  150. 1280  REM ROOM 5
  151. 1290  PRINT "THIS INNER HALLWAY CONTAINS A DOOR TO THE NORTH, A DOOR TO THE WEST, AND A"
  152. 1300  PRINT "CIRCULAR STAIRWELL PASSES THROUGH THE ROOM"
  153. 1315  IF RND>0.6 THEN PRINT "THE ROOM IS SMALL, AND UNFRIENDLY"
  154. 1320  PRINT "YOU CAN SEE AN ORNAMENTAL LAKE THROUGH THR WINDOWS TO THE SOUTH"
  155. 1340  RETURN
  156. 1350  REM ************
  157. 1360  REM ROOM 6
  158. 1370  PRINT "YOU ARE AT THE ENTRANCE TO A FORBIDDING-LOOKING STONE CASTLE. YOU ARE FACING"
  159. 1380  PRINT "EAST"
  160. 1390  RETURN
  161. 1400  REM ************
  162. 1410  REM ROOM 7
  163. 1420  PRINT "THIS IS THE CASTLE'S KITCHEN. THROUGH WINDOWS IN THE NORTH WALL YOU CAN SEE A"
  164. 1430  PRINT "SECRET HERB GARDEN. IT HAS BEEN MANY YEARS SINCE MEALS WERE PREPARED FOR THE"
  165. 1440  PRINT "MONARCH AND THE COURT IN THIS KITCHEN......."
  166. 1443  IF RND>0.4 THEN PRINT "...A RAT SCURRIES ACCROSS THE FLOOR..."
  167. 1450  RETURN
  168. 1460  REM **************
  169. 1470  REM ROOM 8
  170. 1480  PRINT "YOU ARE IN THE STORE ROOM, AMIDST SPICES, VEGETABLES, AND VAST STACKS OF FLOUR"
  171. 1490  PRINT "AND OTHER PROVISIONS. THE AIR IS THICK WITH SPICE AND CURRY FUMES..."
  172. 1520  RETURN
  173. 1530  REM **************
  174. 1540  REM ROOM 9
  175. 1550  PRINT "YOU HAVE ENTERED THE LIFT..."
  176. 1560  GOSUB 3520
  177. 1570  PRINT "IT SLOWLY DESCENDS..."
  178. 1580  GOSUB 3520
  179. 1590  RO=10
  180. 1600  GOTO 1000
  181. 1610  REM *************************
  182. 1620  REM ROOM 10
  183. 1630  PRINT "YOU ARE IN THE REAR VESTIBULE. THERE ARE WINDOWS TO THE SOUTH WHICH YOU CAN SEE"
  184. 1640  PRINT "THE ORNAMENTAL LAKE. THERE IS AN EXIT TO EAST, AND ONE TO THE NORTH."
  185. 1680  RETURN
  186. 1690  REM *****************
  187. 1700  REM ROOM 11
  188. 1710  RETURN
  189. 1720  REM *****************
  190. 1730  REM ROOM 12
  191. 1740  PRINT "YOU ARE IN A DANK, DARK DUNGEON. THERE IS A SINGLE EXIT, AND A SMALL HOLE IN"
  192. 1750  PRINT "THE WALL TOWARDS THE WEST"
  193. 1765  IF RND>0.4 THEN PRINT "...A HOLLOW, DRY CHUCKLE IS HEARD FORM THE GUARD ROOM...."
  194. 1770  RETURN
  195. 1780  REM ****************
  196. 1790  REM ROOM 13
  197. 1800  PRINT "YOU ARE IN THE PRISON GUARDROOM, IN THE BASEMENT OF THE CASTLE. THE STAIRWELL"
  198. 1810  PRINT "ENDS IN THIS ROOM. THERE IS ONE OTHER EXIT, A SMALL HOLE IN THE EAST WALL."
  199. 1820  PRINT "THE AIR IS DAMP AND UNPLEASANT...A CHILL WIND RUSHES INTO THE ROOM FROM GAPS IN"
  200. 1830  PRINT "THE STONE AT THE TOP OF THE WALLS..."
  201. 1840  RETURN
  202. 1850  REM *********************
  203. 1860  REM ROOM 14
  204. 1870  PRINT "YOU ARE IN THE MASTER BEDROOM ON THE UPPER LEVEL OF THE CASTLE...."
  205. 1880  PRINT "LOOKING DOWN FROM THE WINDOW TO THE WEST, YOU CAN SEE THE ENTRANCE TO THE "
  206. 1890  PRINT "CASTLE, WHILE THE SECRET HERB GARDEN IS VISIBLE BELOW THE NORTH WINDOW. THERE"
  207. 1900  PRINT "ARE DOORS TO THE EAST AND TO THE SOUTH...."
  208. 1940  RETURN
  209. 1950  REM *********************
  210. 1960  REM ROOM 15
  211. 1970  PRINT "THIS IS THE L-SHAPED UPPER HALLWAY."
  212. 1971  IF RND>0.4 THEN PRINT "...A MOTH FLITS ACROSS NEAR THE CEILING..."
  213. 1980  PRINT "TO THE NORTH IS A DOOR, AND THERE IS A STAIRWELL IN THE HALL AS WELL. YOU CAN"
  214. 1990  PRINT "SEE THE LAKE THROUGH THE SOUTH WINDOWS"
  215. 2010  RETURN
  216. 2020  REM *********************
  217. 2030  REM ROOM 16
  218. 2040  PRINT "THIS ROOM WAS USED AS THE CASTLE TREASURY IN BY-GONE YEARS....."
  219. 2055  IF RND>0.4 THEN PRINT "...A SPIDER SCAMPERS DOWN THE WALL........"
  220. 2060  PRINT "THERE ARE NO WINDOWS, JUST EXITS TO THE NORTH AND EAST."
  221. 2080  RETURN
  222. 2090  REM *********************
  223. 2100  REM ROOM 17
  224. 2110  PRINT "OOOH...YOU ARE IN THE CHAMBERMIADS' BEDROOM. FAINT PERFUME STILL HANGS IN THE":PRINT "AIR...."
  225. 2120  PRINT "THERE IS AN EXIT TO THE WEST AND A DOOR TO THE SOUTH..."
  226. 2140  RETURN
  227. 2150  REM *********************
  228. 2160  REM ROOM 18
  229. 2170  PRINT "THIS TINY ROOM ON THE UPPER LEVEL IS THE DRESSING CHAMBER. THERE IS A WINDOW TO"
  230. 2180  PRINT "THE NORTH, WITH A VIEW OF THE HERB GARDEN DOWN BELOW. A DOOR IS TO THE SOUTH."
  231. 2210  RETURN
  232. 2215  PRINT "YOU CATCH A GLIMPSE OF YOURSELF IN THE MIRROR HANGING ON THE WALL..."
  233. 2216  PRINT "YOU ARE SHOCKED AT YOUR DISHEVELED APPEARANCE..."
  234. 2220  REM *********************
  235. 2230  REM ROOM 19
  236. 2240  PRINT "THIS IS THE SMALL ROOM OUTSIDE THE CASTLE. YOU CAN SEE THE LAKE THROUGH THE"
  237. 2250  PRINT "SOUTHERN WINDOWS...."
  238. 2280  RETURN
  239. 2290  REM *********************
  240. 2300  REM DEAD END
  241. 2310  PRINT "YOU HAVE DIED........"
  242. 2320  GOSUB 3520
  243. 2330  GOTO 120
  244. 2340  REM *********************
  245. 2350  REM PICK UP TREASURE
  246. 2360  IF A(RO,7)<10 THEN PRINT "THERE IS NO TREASURE TO PICK UP":GOSUB 3520:RETURN
  247. 2370  IF LIGHT=0 THEN PRINT "YOU CANNOT SEE WHERE IT IS":GOSUB 3520:RETURN
  248. 2380  WEALTH=WEALTH+A(RO,7)
  249. 2390  A(RO,7)=0
  250. 2400  RETURN
  251. 2410  REM *********************
  252. 2420  REM UNSUCCESSFUL ATTEMPT TO RUN
  253. 2430  PRINT "NO, YOU MUST STAND AND FIGHT"
  254. 2440  A$="F"
  255. 2450  GOSUB 3520
  256. 2460  GOTO 590
  257. 2470  REM *********************
  258. 2480  REM EAT FOOD
  259. 2490  CLS
  260. 2500  IF FOOD<1 THEN RETURN
  261. 2510  PRINT "YOU HAVE";FOOD;"UNITS OF FOOD"
  262. 2520  PRINT "HOW MANY DO YOU WANT TO EAT";
  263. 2530  INPUT Z
  264. 2540  IF Z>FOOD THEN 2530
  265. 2550  FOOD=INT(FOOD-Z)
  266. 2560  STRENGTH=INT(STRENGTH+5*Z)
  267. 2570  GOSUB 3410:CLS
  268. 2580  RETURN
  269. 2590  REM *********************
  270. 2600  REM INITIALIZE
  271. 2610  CLS
  272. 2620  STRENGTH=60+INT(RND(1)*100)
  273. 2630  WEALTH=30+INT(RND(1)*100)
  274. 2640  FOOD=0
  275. 2650  TALLY=0
  276. 2660  MK=0:REM NO. OF MONSTERS KILLED
  277. 2670  REM *********************
  278. 2680  REM SET UP CASTLE
  279. 2690  DIM A(19,7)
  280. 2700  FOR B=1 TO 19
  281. 2710  FOR C=1 TO 7
  282. 2720  READ A(B,C)
  283. 2730  NEXT C
  284. 2740  NEXT B
  285. 2750  INPUT "WHAT IS YOUR NAME, SHIT";N$
  286. 2760  CLS
  287. 2770  RO=6:REM STARTING POSITION (RO=ROOM NUMBER)
  288. 2780  SWORD=0
  289. 2790  AMULET=0
  290. 2800  AXE=0
  291. 2810  SUIT=0
  292. 2820  LIGHT=0
  293. 2830  REM *********************
  294. 2840  REM ALLOT TREASURE
  295. 2850  FOR J=1 TO 4
  296. 2860  M=INT(RND(1)*19)+1
  297. 2870  IF M=6 OR M=11 OR A(M,7)<>0 THEN 2860
  298. 2880  A(M,7)=INT(RND(1)*100)+10
  299. 2890  NEXT J
  300. 2900  REM *********************
  301. 2910  REM ALLOT MONSTERS
  302. 2920  FOR J=1 TO 6
  303. 2930  M=INT(RND(1)*18)+1
  304. 2940  IF M=6 OR M=11 OR A(M,7)<>0 THEN 2930
  305. 2950  A(M,7)=-J
  306. 2960  NEXT J
  307. 2970  A(4,7)=100+INT(RND(1)*100)
  308. 2980  A(16,7)=100+INT(RND(1)*100)
  309. 2990  RETURN
  310. 3000  REM *********************************
  311. 3010  REM INVENTORY/PROVISIONS
  312. 3020  PRINT "PROVISIONS & INVENTORY"
  313. 3030  GOSUB 3260
  314. 3040  IF WEALTH<0.1 THEN Z=0:GOTO 3137
  315. 3050  PRINT "YOU CAN BUY 1 - FLAMING TORCH ($15)"
  316. 3060  PRINT "            2 - AXE ($10)"
  317. 3070  PRINT "            3 - SWORD ($20)"
  318. 3080  PRINT "            4 - FOOD ($2 PER UNIT)"
  319. 3090  PRINT "            5 - MAGIC AMULET ($30)"
  320. 3100  PRINT "            6 - SUIT OF ARMOR ($50)"
  321. 3110  PRINT "            0 - TO CONTINUE ADVENTURE"
  322. 3131  IF LIGHT=1 THEN PRINT "YOU HAVE A TORCH"
  323. 3132  IF AXE=1 THEN PRINT "YOUR SUPPLIES NOW INCLUDE ONE AXE"
  324. 3133  IF SWORD=1 THEN PRINT "YOU SHOULD GUARD YOUR SWORD WELL"
  325. 3134  IF AMULET=1 THEN PRINT "YOUR AMULET WILL HELP YOU IN TIMES OF STRESS"
  326. 3135  IF SUIT=1 THEN PRINT "YOU LOOK VALIANT IN ARMOR"
  327. 3136  PRINT:INPUT "ENTER NO. OF ITEM REQUIRED";Z
  328. 3137  IF Z=0 THEN CLS:RETURN
  329. 3140  IF Z=1 THEN LIGHT=1:WEALTH=WEALTH-15
  330. 3150  IF Z=2 THEN AXE=1:WEALTH=WEALTH-10
  331. 3160  IF Z=3 THEN SWORD=1:WEALTH=WEALTH-20
  332. 3170  IF Z=5 THEN AMULET=1:WEALTH=WEALTH-30
  333. 3180  IF Z=6 THEN SUIT=1:WEALTH=WEALTH-50
  334. 3190  IF WEALTH<0 THEN PRINT "YOU HAVE TRIED TO CHEAT ME!":WEALTH=0:SUIT=0:LIGHT=0:AXE=0:SWORD=0:AMULET=0:FOOD=INT(FOOD/4):GOSUB 3520
  335. 3200  IF Z<>4 THEN 3030
  336. 3210  INPUT "HOW MANY UNITS OF FOOD";Q:Q=INT(Q)
  337. 3220  IF 2*Q>WEALTH THEN PRINT "YOU HAVEN'T GOT ENOUGH MONEY":GOTO 3210
  338. 3230  FOOD=FOOD+Q
  339. 3240  WEALTH=WEALTH-2*Q
  340. 3250  GOTO 3030
  341. 3260  IF WEALTH>0 THEN PRINT:PRINT:PRINT "YOU HAVE $";WEALTH
  342. 3270  IF WEALTH=0 THEN PRINT "YOU HAVE NO MONEY":GOSUB 3520:RETURN
  343. 3280  FOR J=1 TO 4:PRINT:NEXT J
  344. 3290  RETURN
  345. 3300  REM ****************************
  346. 3310  DATA 0,2,0,0,0,0,0:REM ROOM 1
  347. 3320  DATA 1,3,3,0,0,0,0:REM ROOM 2
  348. 3330  DATA 2,0,5,2,0,0,0:REM ROOM 3
  349. 3340  DATA 0,5,0,0,0,0,0:REM ROOM 4
  350. 3350  DATA 4,0,0,3,15,13,0:REM ROOM 5
  351. 3360  DATA 0,0,1,0,0,0,0:REM ROOM 6
  352. 3370  DATA 0,8,0,0,0,0,0:REM ROOM 7
  353. 3380  DATA 7,10,0,0,0,0,0:REM ROOM 8
  354. 3390  DATA 0,19,0,8,0,8,0:REM ROOM 9
  355. 3400  DATA 8,0,11,0,0,0,0:REM ROOM 10
  356. 3410  DATA 0,0,10,0,0,0,0:REM ROOM 11
  357. 3420  DATA 0,0,0,13,0,0,0:REM ROOM 12
  358. 3430  DATA 0,0,12,0,5,0,0:REM ROOM 13
  359. 3440  DATA 0,15,17,0,0,0,0:REM ROOM 14
  360. 3450  DATA 14,0,0,0,0,5,0:REM ROOM 15
  361. 3460  DATA 17,0,19,0,0,0,0:REM ROOM 16
  362. 3470  DATA 18,16,0,14,0,0,0:REM ROOM 17
  363. 3480  DATA 0,17,0,0,0,0,0:REM ROOM 18
  364. 3490  DATA 9,0,16,0,0,0,0:REM ROOM 19
  365. 3500  REM *****************************
  366. 3510  REM ADJUST LOOP BELOW
  367. 3520  FOR T=1 TO 900:NEXT T
  368. 3530  RETURN
  369.